Group Actions
Engagement
  • Author Author: mayermakes
  • Date Created: Date Created
  • Views 25840 views
  • Likes 16 likes
  • Comments 43 comments
Related
Recommended

Clem's Stepper Motor Puzzle!

mayermakes
Clem's Stepper Motor Puzzle!


Developing electronic circuits often feels like solving a puzzle. And solving this puzzle could win you a Multicomp Pro Tablet Oscilloscope!


And while finding the basic application to make an IC do its magic is often quite easy, some questions often remain.
Among the crucial skills of makers and engineers is interpreting a datasheet and this will come in very handy for the following puzzle:

This time we are looking at a staple of the 3d printing and CNC world:  the TMC2130 stepper motor driver.


imageimage

The photo and schematic show a basic circuit that allows the user to control the movement of a bipolar stepper motor with simple button pushes.
For practical reasons the built circuit has the enable pin(EN) pulled low to activate the circuit.  The Arduino is only used to pass on 12V, 5V and GND to the tmc2130, it has not other connections to the circuit.
Pulling the DIR pin high or low determines the direction of the motor movement.
Pulsing the STEP pin makes the motor move.
But how far does the motor move?

The pins MS1, MS2,MS3 (also known as CFG0,CFG1,CFG2) determine the movement settings; the most widely used configuration is to pull all 3 of them low.
CFG2 determines where to get the voltage reference from. Low level sets it to internal.
The other two pins are much more interesting.
By pulling MS1/CFG0 and MS2/CGF1 low, we set the driver to "Full step," no interpolation and spreadcycle mode.
The most common stepper motors need to do 200 steps per revolution (1,8° angle change per full step).
So for a full rotation we need to press the step button 200 times.

So far so good.

Here is the puzzle:
What happens if you just leave MS1/CFG0 and MS2/CFG1 floating (open) -- how often would you have to push the STEP button for a full rotation?

Or do you think the motor would just not turn at all?

You can find the solution in theory and practice!  We are interested in not only getting the answer right but in seeing the work you did to arrive at this answer.

Tell us if you tried you try it out practically (show us pictures). Or did you study datasheets or video tutorials (share the links you found helpful)?

The member who provides the best detail on how he or she solved the puzzle wins the prize!

Terms and Conditions  Multicomp Pro Tablet Oscilloscope

  • in reply to misaz

    Congratulations on winning and your first oscilloscope! Well deserved prize!

  • in reply to mayermakes

    Thank you for selecting me as a winner of the puzzle. You pronounced my nick very well. I will of course show this interesting oscilloscope to the community very soon after I receive it and write short review. It will be my first oscilloscope. I apply for competitions, design challenges, RoadTests and Project14 regularly, so I think there will be lot of possibilities to see it in my future blogs.

  • Lets go over the main aspekts of the entries for this competition and find out who is the winner!(TLD:DR skip to the end if you just want to know who won)
    The element14 community team will reach out to the winner via DM for the shipping details!
    Congratulations to the winner and all participants, i think this page turned into a really good comprehensive guide to using the TMC2130/ stepper drivers in general!

  • thank you all for your Entries! it has been a blast seeing how this puzzle challenge played out with a lot of different approaches to finding the solution!
    We will carefully review all the entries, even the obvious jokester ones are taken into consideration!

  • in reply to luislabmo

    Here is a small demo where I try the Stepper Driver as is from the factory (SPI Interface by default). This practical demo shows that the stepper driver requires initialization when working in SPI Interface (also indicated in the datasheet).

    I have initialized the stepper driver with the following:

    • Use voltage supplied to AIN as current reference
    • IHOLD=0x10 (~52% max current)
    • IRUN=0x10 (~52% max current)
    • 1 micro-steps (FullStep), TBL=1=24, TOFF=8

    Also to make the test simpler, I'm driving the Step input with a 50% duty cycle PWM signal but the DIR input works normally with the Push-button (seen in the video when changing direction of rotation)

    Below is the sketch used in the Arduino Uno which I've adapted from from the watterott's Github (I've removed the unnecessary things for simplicity).

    // Part of this code was extracted from https://github.com/watterott/SilentStepStick/blob/master/software/TMC2130.ino

#include <SPI.h>

// Connect from Arduino Vin to Vmot, 5V to Vio, and GND

#define STEP_PIN  9 //step

#define CS_PIN   10 //CS chip select
#define MOSI_PIN 11 //SDI/MOSI (ICSP: 4, Uno: 11, Mega: 51)
#define MISO_PIN 12 //SDO/MISO (ICSP: 1, Uno: 12, Mega: 50)
#define SCK_PIN  13 //CLK/SCK  (ICSP: 3, Uno: 13, Mega: 52)

//TMC2130 registers
#define WRITE_FLAG     (1<<7) //write flag
#define READ_FLAG      (0<<7) //read flag
#define REG_GCONF      0x00
#define REG_GSTAT      0x01
#define REG_IHOLD_IRUN 0x10
#define REG_CHOPCONF   0x6C
#define REG_DRVSTATUS  0x6F

uint8_t tmc_write(uint8_t cmd, uint32_t data)
{
  uint8_t s;

  digitalWrite(CS_PIN, LOW);

  s = SPI.transfer(cmd);
  SPI.transfer((data>>24UL)&0xFF);
  SPI.transfer((data>>16UL)&0xFF);
  SPI.transfer((data>> 8UL)&0xFF);
  SPI.transfer((data>> 0UL)&0xFF);

  digitalWrite(CS_PIN, HIGH);

  return s;
}

uint8_t tmc_read(uint8_t cmd, uint32_t *data)
{
  uint8_t s;

  tmc_write(cmd, 0UL); //set read address

  digitalWrite(CS_PIN, LOW);

  s = SPI.transfer(cmd);
  *data  = SPI.transfer(0x00)&0xFF;
  *data <<=8;
  *data |= SPI.transfer(0x00)&0xFF;
  *data <<=8;
  *data |= SPI.transfer(0x00)&0xFF;
  *data <<=8;
  *data |= SPI.transfer(0x00)&0xFF;

  digitalWrite(CS_PIN, HIGH);

  return s;
}

void setup()
{
  //set pins
  pinMode(STEP_PIN, OUTPUT);
  digitalWrite(STEP_PIN, LOW);

  pinMode(CS_PIN, OUTPUT);
  digitalWrite(CS_PIN, HIGH);
  pinMode(MOSI_PIN, OUTPUT);
  digitalWrite(MOSI_PIN, LOW);
  pinMode(MISO_PIN, INPUT);
  digitalWrite(MISO_PIN, HIGH);
  pinMode(SCK_PIN, OUTPUT);
  digitalWrite(SCK_PIN, LOW);

  //init serial port
  Serial.begin(9600); //init serial port and set baudrate
  while(!Serial); //wait for serial port to connect (needed for Leonardo only)
  Serial.println("\nStart...");

  //init SPI
  SPI.begin();
  //SPI.setDataMode(SPI_MODE3); //SPI Mode 3
  //SPI.setBitOrder(MSBFIRST); //MSB first
  //SPI.setClockDivider(SPI_CLOCK_DIV128); //clk=Fcpu/128
  SPI.beginTransaction(SPISettings(1000000UL, MSBFIRST, SPI_MODE3));

  //set TMC2130 config
  tmc_write(WRITE_FLAG|REG_GCONF,      0x00000001UL);  // voltage on AIN is current reference
  tmc_write(WRITE_FLAG|REG_IHOLD_IRUN, 0x00001010UL);  // IHOLD=0x10, IRUN=0x10
  tmc_write(WRITE_FLAG|REG_CHOPCONF,   0x08008008UL);  // FULLSTEP, TBL=1=24, TOFF=8

  //outputs on (LOW active)
  analogWrite(STEP_PIN, 127);
}

void loop()
{
  static uint32_t last_time=0;
  uint32_t ms = millis();
  uint32_t data;
  uint8_t s;
    
  if((ms-last_time) > 1000) //run every 1s
  {
    last_time = ms;

    //show REG_GSTAT
    s = tmc_read(REG_GSTAT, &data);
    Serial.print("GSTAT:     0x0");
    Serial.print(data, HEX);
    Serial.print("\t - ");
    Serial.print("Status: 0x");
    Serial.print(s, HEX);
    if(s & 0x01) Serial.print(" reset");
    if(s & 0x02) Serial.print(" error");
    if(s & 0x04) Serial.print(" sg2");
    if(s & 0x08) Serial.print(" standstill");
    Serial.println(" ");

    //show REG_DRVSTATUS
    s = tmc_read(REG_DRVSTATUS, &data);
    Serial.print("DRVSTATUS: 0x");
    Serial.print(data, HEX);
    Serial.print("\t - ");
    Serial.print("Status: 0x");
    Serial.print(s, HEX);
    if(s & 0x01) Serial.print(" reset");
    if(s & 0x02) Serial.print(" error");
    if(s & 0x04) Serial.print(" sg2");
    if(s & 0x08) Serial.print(" standstill");
    Serial.println(" ");
  }
}

    Luis