As we already used DS18B20 1-wire Digital Thermometer so we will use that data for this purpose also.

Here is the example code based on DFRobot_EC_Test.ino with DS18B20 digital thermometer for temperature compensation calculation. I assume you already download and install OneWire and DallasTemperature Arduino libraries using Library Manager before compiling the code.

For successful compilation, you need to download and install DFRobot_EC library from here. 

/*
 * file DFRobot_EC.ino
 * @ https://github.com/DFRobot/DFRobot_EC
 *
 * This is the sample code for Gravity: Analog Electrical Conductivity Sensor / Meter Kit V2 (K=1.0), SKU: DFR0300.
 * In order to guarantee precision, a temperature sensor such as DS18B20 is needed, to execute automatic temperature compensation.
 * You can send commands in the serial monitor to execute the calibration.
 * Serial Commands:
 *   enterec -> enter the calibration mode
 *   calec -> calibrate with the standard buffer solution, two buffer solutions(1413us/cm and 12.88ms/cm) will be automaticlly recognized
 *   exitec -> save the calibrated parameters and exit from calibration mode
 *
 * Copyright   [DFRobot](http://www.dfrobot.com), 2018
 * Copyright   GNU Lesser General Public License
 *
 * version  V1.0
 * date  2018-03-21
 */

#include <DFRobot_EC.h>
#include <EEPROM.h>
#include <OneWire.h>
#include <DallasTemperature.h>

#define EC_PIN A1         // Using A1 as analog input for EC electrode
#define SENSING_INTERVAL 1000

#if ARDUINO_ARCH_STM32    // for STM32 with 12-bit ADC

#define ADC_REF 3300
#define ADC_STEPS 4096.0
#define TEMP_PIN PB9      // Using pin PB9 as temperature sensor input

#else                     // For AVR Adrduinos with 10-bit ADC

#define ADC_REF 5000
#define ADC_STEPS 1024.0
#define TEMP_PIN 3        // Using pin 3 as temperature sensor input

#endif

DFRobot_EC ec;
OneWire oneWire(TEMP_PIN);
DallasTemperature ds18b20(&oneWire);

void setup() {
  Serial.begin(115200);
  ec.begin();
  ds18b20.begin();
#if ARDUINO_ARCH_STM32
  analogReadResolution(12);
#endif
}

void loop() {
  static unsigned long timer = millis();
  float voltage;
  float temperature;

  if(millis() - timer > SENSING_INTERVAL) {
    timer = millis();
    voltage = analogRead(EC_PIN) / ADC_STEPS * ADC_REF;
    ds18b20.requestTemperatures();                     // send command to get temperaure reading
    temperature = ds18b20.getTempCByIndex(0);          // reading temp in celsius
    float ecValue = ec.readEC(voltage,temperature);    // convert voltage to EC with temperature compensation
    Serial.print("temperature:");
    Serial.print(temperature,1);
    Serial.print(" C, EC:");
    Serial.print(ecValue,2);
    Serial.println("ms/cm");
  }
  ec.calibration(voltage,temperature);
}

More details are here. 

ORP Sensor Interfacing

ORP (Oxidation-Reduction Potential) is a measure of the ability of oxidation and reduction of aqueous solution, characterization of oxidizing or reducing the relative degree. Unlike a pH measurement that follows a logarithmic curve and therefore requires more calibration adjustments, ORP follows a linear relationship and does not need instrument adjustment as much as it needs electrode maintenance. ORP has proven to be a reliable method of measuring water quality and provides the operator with a single value of measurement regardless of which product, commodity, operation, treatment or sanitizer is used, and regardless of varying field conditions or method by which chemical is applied.  

Connect analog data out pin of the sensor to the Arduino A2 pin and upload the following code. 

#define VOLTAGE 5.00    //system voltage
#define OFFSET 0        //zero drift voltage
#define LED 13         //operating instructions
 
double orpValue;
 
#define ArrayLenth  40    //times of collection
#define orpPin 2         //orp meter output,connect to Arduino controller ADC pin
 
int orpArray[ArrayLenth];
int orpArrayIndex=0;
 
double avergearray(int* arr, int number){
  int i;
  int max,min;
  double avg;
  long amount=0;
  if(number<=0){
    printf("Error number for the array to avraging!/n");
    return 0;
  }
  if(number<5){   //less than 5, calculated directly statistics
    for(i=0;i<number;i++){
      amount+=arr[i];
    }
    avg = amount/number;
    return avg;
  }else{
    if(arr[0]<arr[1]){
      min = arr[0];max=arr[1];
    }
    else{
      min=arr[1];max=arr[0];
    }
    for(i=2;i<number;i++){
      if(arr[i]<min){
        amount+=min;        //arr<min
        min=arr[i];
      }else {
        if(arr[i]>max){
          amount+=max;    //arr>max
          max=arr[i];
        }else{
          amount+=arr[i]; //min<=arr<=max
        }
      }//if
    }//for
    avg = (double)amount/(number-2);
  }//if
  return avg;
}
 
 
void setup(void) {
  Serial.begin(9600);
  pinMode(LED,OUTPUT);
}
 
void loop(void) {
  static unsigned long orpTimer=millis();   //analog sampling interval
  static unsigned long printTime=millis();
  if(millis() >= orpTimer)
  {
    orpTimer=millis()+20;
    orpArray[orpArrayIndex++]=analogRead(orpPin);    //read an analog value every 20ms
    if (orpArrayIndex==ArrayLenth) {
      orpArrayIndex=0;
    }   
    orpValue=((30*(double)VOLTAGE*1000)-(75*avergearray(orpArray, ArrayLenth)*VOLTAGE*1000/1024))/75-OFFSET;   //convert the analog value to orp according the circuit
  }
  if(millis() >= printTime)   //Every 800 milliseconds, print a numerical, convert the state of the LED indicator
  {
    printTime=millis()+800;
    Serial.print("ORP: ");
    Serial.print((int)orpValue);
        Serial.println("mV");
        digitalWrite(LED,1-digitalRead(LED));
  }
}

Observe the result to the serial monitor.