Group Actions
Engagement
  • Author Author: urkraft
  • Date Created: Date Created
  • Views 7623 views
  • Likes 17 likes
  • Comments 81 comments
Related
Recommended

(Semi)Automated Plant Irrigation System

urkraft

Semi-automated Plant Irrigation System

Summary

This is an automated system for watering my olive tree.

 

The main components are:

  • A soil moisture sensor
  • A 10 gallon bucket of water with a water level sensor
  • An Adafruit Feather HUZZAH ESP8266 microcontroller (hereafter referred to as “feather”)
  • A peristaltic water pump

 

The two sensors are connected to inputs of the feather, and the water pump is controlled by an output signal from the feather. There are two built in LED’s on the feather:

  • Red: used to indicate that the soil is dry enough to warrant watering
  • Blue: Used to indicate that the bucket is empty (requires a refill of water)

 

There are three criteria which all have to be met in order to turn on the pump (and water the plant):

  1. There must be water in the bucket
  2. The lack of moisture in the soil must be greater than a specified threshold value
  3. A specified minimum amount of time must have elapsed since the pump was last turned off while watering.

 

Any one of the following criteria will cause the pump to be turned off:

  • No water left in the bucket
  • The moisture level of the soil is higher than a specified threshold value (this criteria also triggers starting of the timer which keeps track of the amount of time that has elapsed since the pump was turned off).

 

Basically, the feather just goes in a loop checking the criteria above and taking the necessary action. Each loop iteration takes approximately 20-30 seconds to complete.

 

A feature that I would also like to implement is to have the system send me a message whenever it detects that the water bucket is empty (and possibly send a new reminder each day for a week before giving up). Unfortunately I have not found any official libraries with SMTP capabilities that I can use to accomplish this, so I do not know when or if I will be able to accomplish this goal.

 

I have tested the system quite a bit while implementing it (during the last 2 days) and feel confident that I have found and fixed all of the problems I have encountered along the way, but experience has taught me that the test of time is a very important test – and that test has only just begun.

 

Parts used

 

Schematic Drawing

image

Breadboard

image

Code

#include 

//==========
// CONSTANTS
//==========

// wifi
const char* MY_SSID     = "";
const char* PASSWORD = "";

// I/O
const int LED = 0;  // (Output) indicates pump status (pump ON => LOW signal => lit)
const int PUMP = 4; // (Output) turns water pump on (set LOW) and off (set HIGH)
const int WATER_EMPTY_LED = 2;  // (Output) indicates water reservoir status 
                                // (empty => LOW signal => lit)
const int WATER_LEVEL = 14;  // (Input) to detect water in reservoir (water => HIGH)

// A0 : ADC (Analog Input) used to read soil humidity: high value => dry, low value => wet 
// Max value is approx. 825 - bone dry
// Min value is approx. 470 - drowning in water
const int PUMP_ON_THRESHOLD = 700;  // ADC input value >= this value => Turn on water pump
const int PUMP_OFF_THRESHOLD = 650; // ADC input value <= this value => Turn off water pump
                                    // (and do not turn on again for at least a day)
const long MINIMUM_TIME = 1000 * 60 * 60 * 24; // minimum time between watering (1 day)

//==========
// VARIABLES
//==========

// timing
unsigned long previousMillis = 0;
unsigned long currentMillis = 0;

// soil moisture reading
int moisture = 800; // previous 
int tmpMoisture = 0;  //  new (temporary)

//======
// SETUP
//======

void setup() {
  // initialize Serial
  Serial.begin(115200);
  delay(100);

  Serial.println();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(MY_SSID);

  // initialize info
  WiFi.begin(MY_SSID, PASSWORD);
  WiFi.config(IPAddress(192, 168, 33, 95), IPAddress(192, 168, 33, 1), IPAddress(192, 168, 33, 1));
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");  
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  Serial.println();
  Serial.println();

  Serial.println("Soil moisture sensor");

  // initialize IO
  pinMode(WATER_LEVEL, INPUT);
  pinMode(PUMP, OUTPUT);
  digitalWrite(PUMP, HIGH);
  pinMode(LED, OUTPUT);
  digitalWrite(LED, HIGH);
  pinMode(WATER_EMPTY_LED, OUTPUT);
  digitalWrite(WATER_EMPTY_LED, HIGH);
  delay(2000); // give soil moisture sensor a chance to stabilize
}

void loop() {
  
  // check water reservoir
  while (digitalRead(WATER_LEVEL) == LOW) {  // water reservoir is empty 
    digitalWrite(WATER_EMPTY_LED, LOW);  // turn on the WATER_EMPTY_LED
    digitalWrite(PUMP, HIGH);  // make sure the water pump is turned off
    Serial.println("No water in reservoir => fill it up!");
    soil_moisture(false); // get soil moisture reading and update the soil moisture indicator LED
    // future code to send message at appropriate intervals goes here ...
    delay(10000); // allow moisture sensor to stabilize before next reading
  }
  digitalWrite(WATER_EMPTY_LED, HIGH); // The reservoir has water => turn off the WATER_EMPTY_LED
  soil_moisture(true);  // get the soil moisture reading and do appropriate actions
  delay(10000); // make sure that the moisture sensor gets time to stabilize before next reading
}


void soil_moisture(bool waterAvailable) {
  tmpMoisture = analogRead(A0); // take a soil moisture reading
  if (tmpMoisture != moisture) {  
    // only do the following if the moisture level has changed
    moisture = tmpMoisture;
    // print the moisture data to the serial interface ...
    Serial.print("moisture = ");
    Serial.println(moisture);
    if (moisture >= PUMP_ON_THRESHOLD) { // soil is dry enough for watering ...
      digitalWrite(LED, LOW); // turn on the indicator LED ...
      Serial.print("Dry threshold reached - ");
      if (waterAvailable) { // water is in the reservoir => OK to continue ...
        Serial.print("and water is available - ");
        currentMillis = millis();
        if ((previousMillis == 0) or (currentMillis - previousMillis >= MINIMUM_TIME)) {
          // the appropriate amount of time has transpired since the last watering => OK to water
          digitalWrite(PUMP, LOW);  // turn on pump
          Serial.println("water the plant!");
        } else {
          // not enough time has transpired since last watering => need to wait before watering
          Serial.println("but wait a bit longer.");
        }
      } else {
        // water reservoir is empty ...
        Serial.println("but the water reservoir is empty - fill it up!");
      }
    } else if (moisture <= PUMP_OFF_THRESHOLD) {
        // soil is moist enough ...
        digitalWrite(LED, HIGH);  // turn off the indicator LED
        digitalWrite(PUMP, HIGH); // make sure the water pump is off
        // update previousMillis. Want to wait at least MINIMUM_TIME before next watering
        previousMillis = millis();
        Serial.println("The soil moisture level is high - turning off the water pump.");
    } else {
      // moisture level between thresholds - no action necessary
      Serial.println("The soil moisture level is adequate - no action is being taken.");
    }
  }
}

 

 

Parents

  • Status update:

    Here is a picture of the latest breadboard configuration (although i would be amazed if it would be helpful to anyone as it looks like a rats nest). It is now connected to all the sensors and actuators and being used to keep my olive tree irrigated:

    image

    Schematic Drawing:

    image

    Breadboard Drawing:

    image

    Code:

    /**********************************************************************************************
* Program for semi-automated irrigation using Arduino Uno
* =======================================================
*
* Summary:
* --------
*
* The main components of the system are:
*
* - A soil moisture sensor
* - A 10 gallon bucket of water (water reservoir) with a water level sensor
* - An Arduino Uno (hereafter referred to as “arduino”)
* - A peristaltic water pump
*
* The two sensors are connected to inputs of the arduino, and the water pump is controlled by
* an output signal from the arduino. Two LED’s are used as status indicators:
*
* - Red  : Lit to indicate that the soil is dry enough to warrant watering
* - Blue : Lit to indicate that the water reservoir is empty (requires a refill of water)
*
* There are three criteria which all have to be met in order to turn on the pump (and water
* the plant):
*
* 1)  There must be water in the reservoir
* 2)  The soil moisture reading in the soil must be greater than a specified high threshold
*     value (indicating the soil is too dry)
* 3)  A specified minimum amount of time must have elapsed since the pump was last turned off
*     while watering.
*    
* Any one of the following criteria will cause the pump to be turned off:
*
* - No water left in the water reservoir
* - The moisture reading of the soil is lower than a specified low threshold value
*   (indicating the soil has been irrigated sufficiently. This criteria also triggers the
*   timer which keeps track of the amount of time that has elapsed since the pump was turned
*   off).
*  
* Basically, the arduino just goes in a loop checking the criteria above and taking action
* when necessary. Each loop iteration takes approximately 20-30 seconds to complete.
*
* Future features to impliment:
*
* - display for status and as part of interface for changing threshold values (status: implemented)
* - interface for changing threshold values (status: implemented)
* - ability for messaging when water reservoir is empty or other problems occur
*   (like when the system is restarted to indicate that the custom threshold values
*   need to be reentered.)
* - replace arduino with custom design (with ability to reprogram by attaching adequate
*   IO interface)
*/
#include 
#include 
#include 
#include 


#define OLED_RESET 4
Adafruit_SSD1306 display(OLED_RESET);


#define NUMFLAKES 10
#define XPOS 0
#define YPOS 1
#define DELTAY 2




#define LOGO16_GLCD_HEIGHT 16
#define LOGO16_GLCD_WIDTH  16
#if (SSD1306_LCDHEIGHT != 32)
#error("Height incorrect, please fix Adafruit_SSD1306.h!");
#endif


//==============
// encoder stuff
//==============
#define ENCODER_CLK 2
#define ENCODER_DT 3
#define ENCODER_SW 4

int encoderCounter = 0;
int encoderClkState;
int encoderClkLastState; 
int encoderSwLastState;
int encoderSwState;
int encoderPosition = 0;


// I/O
const int DRY_LED = 13;  // (Output) used to indicate what pump status should be ON (set HIGH) when the pump should be on
const int PUMP = 10; // (Output) used to turn the pump on (set HIGH) and off (set LOW)
const int WATER_EMPTY_LED = 12;  // (Output) used to indicate if the reservoir is empty (set HIGH => ON)
const int WATER_LEVEL = 11;  // (Input) used to detect if there is water in the reservoir (HIGH) or if it is empty (LOW)


// A0 : ADC (Analog Input) used to read soil humidity: high value => dry, low value => wet
// Max value is approx. 1018 - bone dry
// Min value is approx. 530 - drowning in water
const unsigned long MINIMUM_TIME = 1000UL * 60UL * 60UL * 24UL; // minimum time that must transpire between irrigation (1 day)
//const unsigned long MINIMUM_TIME = 60UL * 1000UL; // minimum time that must transpire between irrigation (only for testing)
const unsigned long MAX_PUMP_ON_TIME = 1000UL * 60UL * 15UL; // maximum time pump can be turned on for (15 minutes)
//const unsigned long MAX_PUMP_ON_TIME = 60UL * 1000UL; // maximum time pump can be turned on for (only for testing)


//==========
// VARIABLES
//==========


// timing
unsigned long lastIrrMillis = 0UL;
unsigned long currentMillis = 0UL;
unsigned long pumpOnMillis = 0UL;


// soil moisture reading
int pumpOnThresh = 900;  // Turn on the pump when ADC input value >= this value
int pumpOffThresh = 800; // Turn off the pump when ADC input value <= this value (and do not trun on again for at least a day)
bool pumpIsOn = false;
int moisture = 800; // previous
int waterLevel;


//int tmpMoisture = 0;  //  new (temporary)


int displayLine = 0;
const int DISPLAY_LINE_INCREASE = 8;
const int DISPLAY_LINE_MAX = 32;


//======
// SETUP
//======


void setup() {
  // initialize Serial
  Serial.begin(9600);
  delay(100);


  Serial.println("Soil moisture sensor");


  // initialize IO
  pinMode(WATER_LEVEL, INPUT_PULLUP);
 
  pinMode(PUMP, OUTPUT);
  digitalWrite(PUMP, LOW);
  pumpIsOn = false;
 
  pinMode(DRY_LED, OUTPUT);
  digitalWrite(DRY_LED, LOW);
 
  pinMode(WATER_EMPTY_LED, OUTPUT);
  digitalWrite(WATER_EMPTY_LED, LOW);


  pinMode(ENCODER_CLK, INPUT);
  pinMode(ENCODER_DT, INPUT);
  pinMode(ENCODER_SW, INPUT);
 
  // by default, we'll generate the high voltage from the 3.3v line internally! (neat!)
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);  // initialize with the I2C addr 0x3C (for the 128x32)
  // init done
 
  display.setTextSize(1);
  display.setTextColor(WHITE);
}


void loop() {
  // rotary encoder stuff
  encoderSwState = digitalRead(ENCODER_SW);
  if ((encoderSwLastState == encoderSwState) and (encoderSwState == false)) {
    chooseMenu();
    delay(1000);
  }


  //irrigation stuff
  waterLevel = readInput(WATER_LEVEL);  // read water level
  if (waterLevel == LOW) {  // water reservoir is empty
    digitalWrite(PUMP, LOW); // turn off pump
    pumpIsOn = false;
    digitalWrite(WATER_EMPTY_LED, HIGH); // turn on LED indicator
    // Serial.println("The water reservoir is empty => fill it up!");
  } else {
    digitalWrite(WATER_EMPTY_LED, LOW); // turn off LED indicator
  }
 
  moisture = analogRead(A0);
  if (moisture >= pumpOnThresh) {
    digitalWrite(DRY_LED, HIGH);  // turn on LED indicator
    if (pumpIsOn) {
      currentMillis = millis();
      if ((pumpOnMillis == 0) or ((currentMillis - pumpOnMillis) >= MAX_PUMP_ON_TIME) or (currentMillis < pumpOnMillis)) {
        digitalWrite(PUMP, LOW); // turn pump off
        pumpIsOn = false;
        lastIrrMillis = millis();
      }
    } else {  // pump is off
      currentMillis = millis();
      if ((lastIrrMillis == 0) or (currentMillis - lastIrrMillis >= MINIMUM_TIME)) {
        if (waterLevel == HIGH) {
          digitalWrite(PUMP, HIGH);  // turn on pump
          pumpIsOn = true;
          pumpOnMillis = millis();
        } else {
          // Serial.println("but no water in reservoir!");
        }
      } else {
        // Serial.println("but not enough time has passed since last irrigation.");
      }
    }
  } else if (moisture <= pumpOffThresh) {
    digitalWrite(DRY_LED, LOW); // turn off LED indicator
    if (pumpIsOn) {
      digitalWrite(PUMP, LOW); // turn off pump
      pumpIsOn = false;
      lastIrrMillis = millis();  // update lastIrrMillis in preparation for MINIMUM_TIME criteria calculation
    } else {
      // Serial.println("The soil moisture level is high and the water pump is already off.");
    }
  } else {
    // Serial.println("The soil moisture level is adequate => no action needed.");
  }
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("PumpOnTres: ");
  display.print(pumpOnThresh);
  display.setCursor(0, 8);
  display.print("Value: ");
  display.print(moisture);
  if (pumpIsOn) {
    display.print(" (ON)");
  } else {
    display.print(" (OFF)");
  }
  display.setCursor(0, 16);
  display.print("PumpOffTres: ");
  display.print(pumpOffThresh);
  display.setCursor(0, 24);
  if (waterLevel == LOW) {
    display.print("Bucket is empty.");
  } else {
    display.print("Bucket has water.");
  }
  display.display();
}


int readInput(int input) {
  int millisStep = 20;
  int reading;
  for(int readings = 3; readings; readings--) {
    reading = debounce(digitalRead(input));
    delay(millisStep);
  }
  return reading;
}


int debounce (int SampleA) {
  static int SampleB = 0;
  static int SampleC = 0;
  static int LastDebounceResult = 0;
  LastDebounceResult = LastDebounceResult & (SampleA | SampleB | SampleC) | (SampleA & SampleB & SampleC);
  SampleC = SampleB;
  SampleB = SampleA;
  return LastDebounceResult;
}


void chooseMenu() {
  char* menu[] = {"Change PumpOnTres", "Change PumpOffTres"};
  int menuLen = 2;
  bool skipIt = true;
  int pos = 0;


  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("Choose menu:");
  display.setCursor(0, 8);
  display.print(menu[pos]);
  display.setCursor(0, 16);
  display.print("press dial");
  display.setCursor(0, 24);
  display.print("to set.");
  display.display();
  delay(200);
 
  // Reads the initial state of the ENCODER_SW
  encoderSwLastState = false;
  //delay(80);
  encoderSwState = digitalRead(ENCODER_SW);


  while (!((encoderSwLastState == encoderSwState) and (encoderSwState == false))) {
    encoderSwLastState = encoderSwState;
    encoderSwState = digitalRead(ENCODER_SW);
   
    encoderClkState = digitalRead(ENCODER_CLK);
    if (encoderClkState != encoderClkLastState) {
      if (!skipIt) {
        if (digitalRead(ENCODER_DT) != encoderClkState) {
          pos++;
          pos %= menuLen;
        } else {
          pos--;
          if (pos < 0) {
            pos = menuLen - 1;
          }
        }
        display.clearDisplay();
        display.setCursor(0, 0);
        display.print("Choose menu:");
        display.setCursor(0, 8);
        display.print(menu[pos]);
        display.setCursor(0, 16);
        display.print("press dial");
        display.setCursor(0, 24);
        display.print("to set.");
        display.display();
      }
      skipIt = !skipIt;
    }
    encoderClkLastState = encoderClkState;
  }
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("Choose menu:");
  display.setCursor(0, 8);
  display.print(menu[pos]);
  display.setCursor(0, 16);
  display.print("menu chosen.");
  // display.setCursor(0, 24);
  // display.print(onThresh);
  display.display();
  delay(1000);
  if (pos == 0) {
    pumpOnThresh = getEncoderData("PumpOnTres", pumpOnThresh);
  } else if (pos == 1) {
    pumpOffThresh = getEncoderData("PumpOffTres", pumpOffThresh);
    // pumpOffThresh = setLowThresh();
  }
}


int getEncoderData(char* theParam, int startPos) {
  bool skipIt = true;
  // int onThresh = pumpOnThresh;


  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("Change ");
  display.print(theParam);
  display.print(":");
  display.setCursor(0, 8);
  display.print(startPos);
  display.setCursor(0, 16);
  display.print("press dial");
  display.setCursor(0, 24);
  display.print("to set.");
  display.display();
  delay(200);
 
  // Reads the initial state of the ENCODER_SW
  encoderSwLastState = false;
  encoderSwState = digitalRead(ENCODER_SW);


  while (!((encoderSwLastState == encoderSwState) and (encoderSwState == false))) {
    encoderSwLastState = encoderSwState;
    encoderSwState = digitalRead(ENCODER_SW);
   
    encoderClkState = digitalRead(ENCODER_CLK);
    if (encoderClkState != encoderClkLastState) {
      if (!skipIt) {
        if (digitalRead(ENCODER_DT) != encoderClkState) {
          if (startPos < 1023) {
            startPos++;
          }
        } else {
          if (startPos > 0) {
            startPos--;
          }
        }
        display.clearDisplay();
        display.setCursor(0, 0);
        display.print("Change ");
        display.print(theParam);
        display.print(":");
        display.setCursor(0, 8);
        display.print(startPos);
        display.setCursor(0, 16);
        display.print("press dial");
        display.setCursor(0, 24);
        display.print("to set.");
        display.display();
      }
      skipIt = !skipIt;
    }
    encoderClkLastState = encoderClkState;
  }
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("Change ");
  display.print(theParam);
  display.print(":");
  display.setCursor(0, 8);
  display.print(startPos);
  display.setCursor(0, 16);
  display.print(theParam);
  display.print(" set to");
  display.setCursor(0, 24);
  display.print(startPos);
  display.display();
  delay(1000);
  return startPos;
}

    This phase of the project is now undergoing the final tests in full function modus. While this is in progress i plan to shift my focus towards finding a solution for the messaging i wanted to implement.

    -raymond

  • in reply to urkraft

    Just another little tip, but there is a 'Syntax Highlighting' option in the blog editor which can help present your code:

    image

     

    e.g.:

    void loop() {
  // rotary encoder stuff
  encoderSwState = digitalRead(ENCODER_SW);
  if ((encoderSwLastState == encoderSwState) and (encoderSwState == false)) {
    chooseMenu();
    delay(1000);
  }

  • in reply to beacon_dave

    Thank you very much for the tip Dave! Fantastic!

    Regards,

    -raymond

Comment Children
No Data