arduino .

Question

can anyone please help me with my arduino codes. I am beginner with arduino. I am writing a code to control my 50hz laser externally. my code needs to be have 2 functions. 1. need to give a continues pulse of 20milliseconds. 2. when i trigger the switch, I should get one single pulse of 20ms with a required delay. both these pulses are different. but i have tried with some coding. the problem with my code is that when i press the trigger, I will get one single pulse, but it will stop the 1st 50hz continues pulse. @ my codes are given below, If you have any idea can you please help me. also i have given the images from oscilloscope. int button = 4; int out = 12; int out1 = 8; int valueout = 0; int val = 0; void setup() { pinMode(button, INPUT); pinMode(out, OUTPUT); pinMode(out1, OUTPUT); } void loop() { { digitalWrite(out, HIGH); delay(19.6); valueout = 1; digitalWrite(out, LOW); delayMicroseconds(400); valueout = 0; } { val = digitalRead(button); } { val = digitalRead(button); if (valueout == 0 && val == HIGH){ delayMicroseconds(1000); digitalWrite(out1, HIGH); delay(19); digitalWrite(out1, LOW); delay(1000);} else{ digitalWrite(out1, LOW);} } } 
 Attachments:

kulky64 · Answer

ATmega328 has a nice 16-bit Timer/Counter1 with two outputs OC1A and OC1B - exactly what you need. All you have to do is setup some registers and make one or two ISRs.

tonyboubady · Answer

We can achieve this with pure code... this is what shabaz said too Just use one delay function in microsecond for base loop, and use variable counter as timers for various purpose. for example... use delayMicroseconds(100); as base loop timer and use variable counters to add up and counting time. The base loop is loops around in every 100 microsecond, so to count to 1 millisecond then it takes 10 times to run the loop, 20 times = 2ms, 30 times = 3ms and so on... like... int timer_high = 1; int timer_ low = 1; int timer_high2 = 1; int timer_ low2 = 1; void loop() { if ( timer_high == 1000) { // it is 100ms delay digitalWrite(out, HIGH); timer_high = 1; } if ( timer_ low == 5000) { // it is 500ms delay digitalWrite(out, LOW); timer_ low = 1; } if ( timer_high2 == 2) { // it is 200us delay // do something timer_high2 = 1; } if (timer_low2 == 5) { // it is 500us delay // do something timer_low2 = 1; } delayMicroseconds(100); timer_high++; timer_ low ++; timer_high2++; timer_ low2++; } with this example code you can control delays with various frequency and multiple inputs and outputs simultaneously... This code is not exact solution for you, but it's the base.

shabaz · Answer

Hi Gladson, Without writing the code for you but just describing how you could go about this to give you some ideas: There are a few ways, one method is, only have a single delay statement in your code, and that delay statement can be for (say) 20 microseconds. If you want to delay things for (say) 400 microseconds, then that is the same as repeating a 20 microseconds delay 20 times. You can use variables to record how many times you have repeated, and the state each output should be in. You can also check for button-presses each 20 microseconds as part of this. Similarly a delay of 1000 microseconds can be considered to be a delay of 20 microseconds repeated 50 times. In summary, it would be possible to re-write the code so that there is only one delay statement, and create some variables that contain counts and the status of each output, and a variable where you store the button press status, and so on, and perform your output actions accordingly, each 20 microseconds. If you think about it, this is like a 'tick' every 20 microseconds, and on each tick you perform your tasks (like reading the button input, and updating the outputs as desired. But the code as described has its disadvantages! You'll notice these if you try to subsequently add more functionality and see the change in speed. You can resolve that by making your 'tick' on time using the Arduino timer library, i.e. your code becomes event driven, where the event is the 20 microsecond tick from the timer. It then doesn't matter what additional features you add, provided they can execute within the time before the next timer event occurs.

kulky64 · Answer

The question is not how you generate this interrupt, but how you will make second pulse without disrupting your first periodic pulse. Try this sketch: int pulse_periodic_50hz = 9;

void setup() 
{
 pinMode(pulse_periodic_50hz, OUTPUT);
 TCCR1A = 0x82;
 TCCR1B = 0x1A;
 ICR1 = 39999;
 OCR1A = 39199;
 OCR1B = 799;
} 
 
void loop() 
{ 
 // do nothing 
} This should generate your periodic pulse with 50 Hz frequency with t_high = 19.6ms and t_low = 400us. Connect scope to pin 9 a let me know if it works. Once you have this working, you are halway there.

kulky64 · Answer

My bad, i have corrected it. Try now.

kulky64 · Answer

Good. This program does one more thing i haven't told you about. It sets bit OCF1B in TIFR1 register exactly 400 us (you wanted 200-600us, so i used the middle) after rising edge of your periodic pulse in every period. You can use this bit to synchronize your one-shot pulse with 50Hz periodic signal. Now you have several options: - you can do the rest using interrupts a let the same timer also generate your one-shot pulse after button is pressed. Loop function will stay empty. - or you can do it with polling in loop function (probably easier for you). Wait for button to be pressed (make sure it is properly debounced), and after button is pressed wait until OCF1B bit in TIFR1 register is set (this will happen 400 us after closest rising edge on periodic signal) and then generate your pulse using delay functions as before. Now your first periodic signal will not be disrupted by generation of this pulse, because timer takes care of generation of this signal and you can forget about it.

kulky64 · Answer

Try this. Dunno if it works. int pulse_periodic_50hz = 9;
int pulse_20ms = 8;
int button = 2;

void setup()
{
 pinMode(pulse_periodic_50hz, OUTPUT);
 pinMode(pulse_20ms, OUTPUT);
 pinMode(button, INPUT);
 
 TCCR1A = 0x82;
 TCCR1B = 0x1A;
 ICR1 = 39999;
 OCR1A = 39199;
 OCR1B = 799;
}
 
void loop()
{
 if(digitalRead(button))
 {
 delay(10); // debounce
 while(digitalRead(button)); // wait for release
 
 TIFR1 |= (1<<OCF1B); // clear OCF1B flag
 while(!(TIFR1&(1<<OCF1B))); // wait till OCF1B flag is set
 
 digitalWrite(pulse_20ms, HIGH);
 delay(20);
 digitalWrite(pulse_20ms, LOW);
 }
}

kulky64 · Answer

My fault again. I forgot, that OCF1B is cleared by writing a logic one instead of logic zero. Modify line 25 to: TIFR1 |= ( 1<<OCF1B); instead of TIFR1 &= ~( 1<<OCF1B);

kulky64 · Answer

Bingo. Output frequency is given by this formula in the datasheet:

f_clk_IO = 16 MHz

N = 8 as you already figured out is the prescaler

TOP is given by value in ICR1 in mode 14 (notice how value in TOP is increased by 1 for reason discussed above, so 39999 is increased to round 40000)

This gives:

f_OCnxPWM = 16E+6 / (8*(1+39999)) = 50 Hz

kulky64 · Answer

The way counter is set up with the prescaler=8, the content of TCNT1 register is incremented every half microsecond ( (16 MHz / 8)^-1 = 0.5us ) and it counts from zero to 39999 and then restarts from zero again. As counter counts, the content of TCNT1 is constanly compared to values in registers OCR1A and OCR1B. When there is compare match between TCNT1 and OCR1A or OCR1B, the corresponding flag (bits OCF1A or OCF1B in TIFR1 register) is set. Normally these flags are used to trigger an interrupt, when corresponing interrupt enable bits in TIMSK1 register are set. OCF1A and OCF1B flags are automatically cleared by hardware when the corresponding ISR is executed. We have set OCR1B = 799, so compare match will occur 0.5us*(1+799) = 400 us after counter rolls over from 39999 to 0. Since we didn't use interrupts in our program, the corresponding OCF1B flag is not automatically cleared by harware every period and is constantly set to 1. Until the button is pressed. Then we clear this flag manually by writing a logical one to it. This is done by this line:

TIFR1 |= (1<<OCF1B);

And then we wait until it is set again on the nearest compare match between TCNT1 and OCR1B and we generate our 20 ms pulse.

arduino .

Top Replies