Need help editing arduino code

Question

After my timer runs out i want my buzzer to buzz 5 times. Right now it buzzes once this is my code. What would i change to beep more than once

#include <LiquidCrystal.h>

const int
    RS = 12,
    EN = 11,
    D4 = 5,
    D5 = 4,
    D6 = 3,
    D7 = 2;
const int
    pinActiveBeeper = 7;    //whatever pin you're using for the active beeper

LiquidCrystal lcd( RS, EN, D4, D5, D6, D7 );

const unsigned long
    culPeriod = 5ul*60ul*1000ul; //5 minutes x 60 seconds/min x 1000mS/second

//nice string generation for LCD and serial monitor
char
    szStr[16];
//timer variables
// timeStart is set in setup() and marks the beginning of the countdown
// timeNow is updated each pass of the loop and used to check how much time (in milliseconds) has elapsed
unsigned long
    timeNow,
    timeStart;

void setup()
{
    //set up the serial monitor
    Serial.begin(9600);
    //initialize the 16x2 LCD, clear it and print "Countdown" on the first line
    lcd.begin(16, 2);
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Countdown:");

    pinMode( pinActiveBeeper, OUTPUT );
    digitalWrite( pinActiveBeeper, LOW );

    //get the time marking the beginning of the countdown
    timeStart = millis();

}//setup

void loop()
{
    //these "static" variables are used to know when to update the display
    //basically, when one of the minutes, seconds or tenths changes, the display
    //is updated and a message sent to the serial monitor
    static unsigned long
        lastminutes = 0,
        lastseconds = 0,
        lasttenths = 0;
    //from the time remaining in milliseconds, calculate the "human readable" min/sec/tenths
    unsigned long
        minutes,
        seconds,
        tenths;
    unsigned long
        timeRemaining;

    //get the millisecond count now
    timeNow = millis();

    //culPeriod is set to the number of milliseconds in 5 minutes (5 x 60 x 1000)
    //if the difference between the time we started setup() and now is equal to
    //or greater than that value the countdown is done
    if( (timeNow-timeStart) < culPeriod )
    {
        //not there yet; calc the time remaining in milliseconds
        timeRemaining = culPeriod - (timeNow - timeStart);
        //conver to minutes, seconds and tenths of a second
        minutes = timeRemaining / 60000ul;
        seconds = (timeRemaining - (minutes * 60000ul))/1000ul;
        tenths = (timeRemaining - (minutes * 60000ul) - (seconds * 1000ul)) / 100ul;
        //if any of those digits has changed since the last pass, send the updated
        //values to the LCD and serial monitor
        if( (minutes != lastminutes) || (seconds != lastseconds) || (tenths != lasttenths) )
        {
            sprintf( szStr, "%lu:%02lu:%d", minutes, seconds, tenths );
            Serial.println( szStr );
            lcd.setCursor(0, 1);
            lcd.print( szStr );
            //update the last values with the current values
            lastminutes = minutes;
            lastseconds = seconds;
            lasttenths = tenths;

        }//if

    }//if
    else
    {
        //sound the active beeper (assumes a high on the pin turns it on) for 1-second
        Serial.println( "Beep on" );
        digitalWrite( pinActiveBeeper, HIGH );
        //normally don't use delay but since the action right after this is to halt and catch fire, why not?
        delay(1000);
        Serial.println( "Beep off" );
        digitalWrite( pinActiveBeeper, LOW );

        //halt and wait for reset to re-do countdown
        while(1);

    }//else

}//loop

baldengineer · Answer

for (int x; x<5; x++) {
 digitalWrite( pinActiveBeeper, HIGH );
 //normally don't use delay but since the action right after this is to halt and catch fire, why not?
 delay(1000);
 Serial.println( "Beep off" );
 digitalWrite( pinActiveBeeper, LOW );
 delay(1000);
}

baldengineer · Answer

If you're just going to while(1) after the buzzing is done anyway, just turn the buzzer on and off 5 times. You could either do multiple digitalWrite(HIGH) and digitalWrite(LOW) or use a for() loop.

neilk · Answer

There's a lot going on in your code. Sometimes it's difficult to see the wood because the trees get in the way!!!

Why not write a simple sketch, using the guidance from baldengineer and kulky64, which just sounds your buzzer 5 times. When you get that working, you can add it to your main sketch.

Neil

kulky64 · Answer

Try initialize variable x to 0 in your for cycle, like this: for ( int x=0; x< 5 ; x++)

baldengineer · Answer

Your original statement was that your code provided a single beep. All I did was use a loop to repeat that code 5 times. So if now you get zero beeps, then the code you are using now must be different from what you posted above. If you are seeing the "on" and "off" messages in the serial monitor then it is a hardware issue. It would be helpful to know what kind of buzzer it is. Not all buzzers are self-excited and may require a tone() (PWM signal) to active it.

gecoz · Answer

The while(1) endless loop is only reached when the condition: ((timeNow-timeStart) < culPeriod ) is evaluated false (else branch). Till then, the loop() gets invoked repeatedly, thus justifying the need for static variables to retain the values, updated in the if branch of the test above, between loop() calls.

baldengineer · Answer

Use the suggestion from @kulky64. I've run into that problem in the past. Change the for-statement to: for (int x=0; x<5; x++) { I might have lead you astray on that one.

Need help editing arduino code

Top Replies