Blog#3 Implementation (Case Enclosure Reliability Monitor)

/*
MKR_LoRa_SENDER_InTemp
This sketch will get the temprture from a DS18B20 Temperature Sensor attached to the MKR WAN 1300
Each time the loop runs, we will send a "packet" containing the message "InTemp:<temp>
the value of <temp> will contain the current tempreture from the sensor
The packet will be sent

1-20-2020 Added OLED Adafruit_SSD1306 support.

*/

// MKRWAN - Version: 1.0.15
#include <MKRWAN.h>

#include <SPI.h>
#include <LoRa.h>

#include <OneWire.h>
#include <DallasTemperature.h>

// Include Adafruit Graphics & OLED libraries
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define ONE_WIRE_BUS 2
//#define ONE_WIRE_BUS 4

OneWire oneWire(ONE_WIRE_BUS);

DallasTemperature sensors (&oneWire);

float temperature= 0.0;
float Fahrenheit = 0.0;

// OLED CODE for MKR WAN 1300
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels
// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#define OLED_RESET 4 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

void setup() {
Serial.begin(9600);
/*while (!Serial);*/

Serial.println("LoRa Sender");

if (!LoRa.begin(915E6)) {
Serial.println("Starting LoRa failed!");
while (1);
}

// OLED CODE
// Start Wire library for I2C
Wire.begin();
// initialize OLED with I2C addr 0x3C
display.begin(SSD1306_SWITCHCAPVCC, 0x3C);

}

// oled dispaly tempreture
void displayValues(float v){
// Delay to allow sensor to stabalize
delay(2000);
// Clear the display
display.clearDisplay();
//Set the color - always use white despite actual display color
display.setTextColor(WHITE);
//Set the font size
display.setTextSize(1);
//Set the cursor coordinates
display.setCursor(25,0);
display.print("Temprature");
display.setCursor(33,12);
display.setTextSize(3);
display.print(v);
}

void loop() {
Serial.print("Sending packet: ");
Serial.println(Fahrenheit);

// send packet
LoRa.beginPacket();
LoRa.print("inTemp:");
LoRa.print(Fahrenheit);
LoRa.endPacket();

//getting temperature
sensors.requestTemperatures(); //send command for readings

temperature = sensors.getTempCByIndex(0); // VALUE RETURNED IN cELCIUS
// Why "byIndex"?
// You can have more than one DS18B20 on the same bus.
// 0 refers to the first IC on the wire

//Fahrenheit = temperature;
Fahrenheit=sensors.toFahrenheit(temperature); // convert temp into Fahrenheit
//Serial.println(Fahrenheit);

// display the temp on OLED
displayValues(Fahrenheit);
display.display();

delay(5000);
}

/*
MKR_LoRa_Receiver
we will not be creating any packets. Instead, we will listen to incoming ones.
1-20-2020 Added OLED Adafruit_SSD1306 support.

*/
// MKRWAN - Version: 1.0.15
#include <MKRWAN.h>

#include <SPI.h>
#include <LoRa.h>

// Include Adafruit Graphics & OLED libraries
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// CODE for MKR WAN 1300
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#define OLED_RESET 4 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

String inputString = ""; // a String to hold incoming data

void setup() {
Serial.begin(9600);
Serial1.begin(9600);
while (!Serial);

Serial.println("LoRa Receiver");

if (!LoRa.begin((915E6))) {
Serial.println("Starting LoRa failed!");
while (1);
}

// reserve 200 bytes for the inputString:
inputString.reserve(200);

//OLED CODE
// Start Wire library for I2C
Wire.begin();
// initialize OLED with I2C addr 0x3C
display.begin(SSD1306_SWITCHCAPVCC, 0x3C);

}

// OLED DISPLAY FUNCTION to display numbers.
void displayValues(String v){
// Delay to allow sensor to stabalize
delay(2000);
// Clear the display
display.clearDisplay();
//Set the color - always use white despite actual display color
display.setTextColor(WHITE);
//Set the font size
display.setTextSize(1);
//Set the cursor coordinates
display.setCursor(25,0);
display.print("Rcvd Packet");
display.setCursor(33,12);
display.setTextSize(3);
display.print(v);
}

void loop() {
// try to parse packet
int packetSize = LoRa.parsePacket();
if (packetSize) {
// received a packet
Serial.print("Received packet '");

// read packet
while (LoRa.available()) {
//Serial.print((char)LoRa.read());
// get the new byte:
char inChar = (char)LoRa.read();
// add it to the inputString:
inputString += inChar;
}

// display on OLED
displayValues(inputString);
display.display();

Serial.print(inputString);
Serial1.print(inputString);
Serial1.print('\n');
// print RSSI of packet
Serial.print("' with RSSI ");
Serial.print(LoRa.packetRssi());
Serial.println("");
inputString = "";
}
}

/*
Sketch generated by the Arduino IoT Cloud Thing "Counter"
https://create.arduino.cc/cloud/things/8365259b-0af3-440e-add6-fc53e82ea22d

Arduino IoT Cloud Variables description

The following variables are automatically generated and updated when changes are made to the Thing

String counter;
int int_Counter;

Variables which are marked as READ/WRITE in the Cloud Thing will also have functions
which are called when their values are changed from the Dashboard.
These functions are generated with the Thing and added at the end of this sketch.
*/

#include "thingProperties.h"
String inputString = ""; // a String to hold incoming data
bool stringComplete = false; // whether the string is complete

float retFloat(String stringOne) {
// Given a tuple pair in the form varname:value ex. inTemp:1.1
// return a float value to the right of the cloen character
//Serial.println(stringOne);
int firstClosingBracket = stringOne.indexOf(':');
String value = String(stringOne.substring(firstClosingBracket+1));
//Serial.println(value);
float Temp = value.toFloat();
return Temp;
}
void setup() {
// Initialize serial and wait for port to open:
Serial.begin(9600);
Serial1.begin(9600);

while (!Serial) {
; // wait for serial port to connect. Needed for native USB port only
}

// Defined in thingProperties.h
initProperties();

// Connect to Arduino IoT Cloud
ArduinoCloud.begin(ArduinoIoTPreferredConnection);

/*
The following function allows you to obtain more information
related to the state of network and IoT Cloud connection and errors
the higher number the more granular information you’ll get.
The default is 0 (only errors).
Maximum is 4
*/
setDebugMessageLevel(2);
ArduinoCloud.printDebugInfo();
}

void loop() {
ArduinoCloud.update();
// Your code here

// use the string when a newline arrives:
if (stringComplete) {
Serial.print("received on RX PIN:");
Serial.print(inputString);

//USE THE InputString HERE
counter = inputString;
int_Counter++;
inTemp = retFloat(inputString);
Serial.print("Sending value = ");
Serial.println(inTemp);
//ArduinoCloud.update();
// clear the string:
inputString = "";
stringComplete = false;
}

//At the very end of the loop check for serial data
serialEvent();
}

/*
Since Counter is READ_WRITE variable, onCounterChange() is
executed every time a new value is received from IoT Cloud.
*/
void onCounterChange() {
// Add your code here to act upon Counter change
}

/*
SerialEvent occurs whenever a new data comes in the hardware serial RX. This
routine is run between each time loop() runs, so using delay inside loop can
delay response. Multiple bytes of data may be available.
*/
void serialEvent() {
while (Serial1.available()) {
// get the new byte:
char inChar = (char)Serial1.read();
// add it to the inputString:

inputString += inChar;
// if the incoming character is a newline, set a flag so the main loop can
// do something about it:
if (inChar == '\n') {
stringComplete = true;
}
}
}

/*
Since IntCounter is READ_WRITE variable, onIntCounterChange() is
executed every time a new value is received from IoT Cloud.
*/
void onIntCounterChange() {
// Add your code here to act upon IntCounter change

}

II placed it in my garage a few hours

I placed  it outside overnight.

It was about 27F that night and a dusting of snow fell during the night

In the morning I placed the temp probe into the snowbank
and to my surprise the temperature only lowered a few degrees. 

My final test was to place the Enclosure into my personal sauna
for about 6 hours.
I was able to get the Temperature in the Sauna up to 107F degrees.

Here are the graphs showing the temperature changes as I moved the 
Enclosure to the different Environments

GRAPH of all environments over 24 hours

GRAPH of the time of the enclosure in my sauna

Blog#3 Implementation (Case Enclosure Reliability Monitor)