Relay sketch required for a charity project.

Nico,

Firstly thankyou for your help - fantasticly quick response!

I have just got in from work and tested the sketch. I think it's pretty much there however it's kinda working backwards I think.

When the arduino is powered all 3 relays are 'active'

I have timed the relays changing state, here is what happens:

Arduino powered - R1,2 & 3 'On'

Button Pressed - R1 'Off'

10 seconds - R2 'Off'

22 seconds - R3 'Off' (R1,2 & 3 'Off)

1 min 40 seconds - R3 'On'

1 min 52 seconds - R1,2 & 3 'On'

Basically what's on should be off & what's off should be on.

The pushbuton does start the sequence when pushed and when a second press is made it re-sets which is perfect.

Hope it's not too difficult to modify.

Thanks again.

VB (Kris)

Nico,

Firstly thankyou for your help - fantasticly quick response!

I have just got in from work and tested the sketch. I think it's pretty much there however it's kinda working backwards I think.

When the arduino is powered all 3 relays are 'active'

I have timed the relays changing state, here is what happens:

Arduino powered - R1,2 & 3 'On'

Button Pressed - R1 'Off'

10 seconds - R2 'Off'

22 seconds - R3 'Off' (R1,2 & 3 'Off)

1 min 40 seconds - R3 'On'

1 min 52 seconds - R1,2 & 3 'On'

Basically what's on should be off & what's off should be on.

The pushbuton does start the sequence when pushed and when a second press is made it re-sets which is perfect.

Hope it's not too difficult to modify.

Thanks again.

VB (Kris)

Hi Kris,

I wrote it so that a line going HIGH means "ON", which I guess happens to be backwards

To reverse that we just need to switch my HIGHs and LOWs wherever it says "digitalWrite(RELAY...".

I just checked my own relay board, and noticed that my relays behave the same as yours, where LOW = ON, and HIGH = OFF.

I added #define's for easy switching of HIGH/LOW, in case some other relay boards behave differently in the future.

I also noticed that I was wasting a bit of memory for constants, so I made them into #define's, which is more elegant.

ps, you can use Serial monitor to see the debug messages I included.

So here is the updated code:

/*

Customized Vehicle, with options controlled by Arduino

Written by Nico teWinkel

www.mulBerryLand.com

*/

#define RELAY_ON  LOW

#define RELAY_OFF HIGH

// these are the pins the relays are connected to

#define RELAY1 2

#define RELAY2 3

#define RELAY3 4

//#define RELAY4 5

// this is where the momentary switch is connected

#define STARTBUTTON 8

// set up the start and stop times, in milliseconds

// relay1 starts immediately

#define RELAY2_START_TIME 10000   // 0:10

#define RELAY3_START_TIME 22000   // 0:22

#define ACTION_STOP_TIME 112000   // 1:52    - stops relays 1 and 2

#define RELAY3_STOP_TIME 100000   // 1:40

// this keeps track of the time since the button press

long startTime;

long lastTimeButtonPressed;

long lastOutputTime;

// active is TRUE when the actions are happening

boolean active;

boolean relay2_active;

boolean relay3_active;

void setup() {

  // start the serial for debug

  Serial.begin(9600);

  Serial.println("Starting application.");

  // set the relay pins as outputs

  pinMode(RELAY1, OUTPUT);

  pinMode(RELAY2, OUTPUT);

  pinMode(RELAY3, OUTPUT);

  //pinMode(RELAY4, OUTPUT);

  // make sure the relays are all off to start with

  digitalWrite(RELAY1, RELAY_OFF); // turn off relay1

  digitalWrite(RELAY2, RELAY_OFF); // turn off relay2

  digitalWrite(RELAY3, RELAY_OFF); // turn off relay3

  // set the pushbutton pin as an input

  pinMode(STARTBUTTON, INPUT);

  startTime = 0;

  active = false;

  relay2_active = false;

  relay3_active = false;

  lastTimeButtonPressed = -1000; // to avoid the initial 1 second button ignore

  lastOutputTime = 0;

}

void loop() {

  // check for button push

  // read the state of the switch into a local variable:

  int reading = digitalRead(STARTBUTTON);

  // ignore if button is pressed more than once per second

  // this also simplifies debounce

  if (millis() - lastTimeButtonPressed > 1000 && reading == HIGH) {

    lastTimeButtonPressed = millis();

    Serial.println("Button was pressed.");

    if (active) {

      // pushing the button when things are going on stops everything

      digitalWrite(RELAY1, RELAY_OFF); // turn off relay1

      digitalWrite(RELAY2, RELAY_OFF); // turn off relay2

      digitalWrite(RELAY3, RELAY_OFF); // turn off relay3

      active = false;

    }

    else {

      active = true;

      startTime = millis();

      Serial.println("Turning ON relay 1");

      digitalWrite(RELAY1, RELAY_ON); // turn on relay1

    }

  }

  if (active) {

    // show time once per second

    if((millis() - lastOutputTime) > 1000) {

      Serial.print("Time: ");

      Serial.println((millis() - startTime) / 1000);

      lastOutputTime = millis();

    }

    if (!relay2_active && millis() - startTime > RELAY2_START_TIME && millis() - startTime < ACTION_STOP_TIME) {

      Serial.println("Turning ON relay 2");

      digitalWrite(RELAY2, RELAY_ON); // turn on relay2

      relay2_active = true;

    }

    if (!relay3_active && millis() - startTime > RELAY3_START_TIME && millis() - startTime < RELAY3_STOP_TIME) {

      Serial.println("Turning ON relay 3");

      digitalWrite(RELAY3, RELAY_ON); // turn on relay3

      relay3_active = true;

    }

    if (relay3_active && millis() - startTime > RELAY3_STOP_TIME) {

      Serial.println("Turning OFF relay 3");

      digitalWrite(RELAY3, RELAY_OFF); // turn off relay3

      relay3_active = false;

    }

    if (active && millis() - startTime > ACTION_STOP_TIME) {

      Serial.println("Turning OFF all relays");

      // stop everything

      // relay3 should already be off,

      //   but this makes sure it's all off in case there was a delay

      digitalWrite(RELAY1, RELAY_OFF); // turn off relay1

      digitalWrite(RELAY2, RELAY_OFF); // turn off relay2

      digitalWrite(RELAY3, RELAY_OFF); // turn off relay3

      active = false;

      relay2_active = false;

      relay3_active = false;

    }

  }

}