Please I need help Writing code

Hello Edward,

I am sorry to miss your question, thanks to tariq.ahmad  now I am on the piece Don't worry we can easily solve your problem; BTW, maybe many users say that the problems are easy. I always found easy the problems I already know the solution

I ask you a favor, please. Take a look in the editor features and add the code with Syntax Highlighting so I can easily copy and past it in one Arduino board here to make some test and solve it faster. It was my browser rendering wrond your sources, now I can see them correctly. So, go ahead.

As far as I see lights may flash with your code but this approach IMHO may create difficulties implementing the other part, better if we use a couple of separate functions. Let me know as I am almost available to follow you these days.

Wait for your code to try it together. What is the Birthday deadline?

Enrico

As waiting for your code I mean your last update after the mcb1 suggestions eventually applied.

Enrico

[code]
/*
Railroad crossing controller
*/
#include 

// Constants
const int CYCLE_PERIOD_MS = 10;

const int SENSOR_DELTA_THRESHOLD = 20;

const int BELL_RING_PERIOD = 400;
const int BELL_RING_CYCLES = BELL_RING_PERIOD / CYCLE_PERIOD_MS;
const int BELL_TONE_FREQUENCY = 300;
const int BELL_DURATION = 180;

const int LIGHT_BLINK_PERIOD = 1000;
const int LIGHT_BLINK_CYCLES = LIGHT_BLINK_PERIOD / CYCLE_PERIOD_MS;
const int LIGHT_BLINK_HALF_CYCLES = LIGHT_BLINK_CYCLES / 2;

const float CROSSING_POSITION_RAISED = 110.0;
const float CROSSING_POSITION_LOWERED = 15.0;
const float CROSSING_DEGREES_PER_CYCLE = 0.1;

const int TRAIN_SPEED_MS_PER_SECTION = 1000;
const int TRAIN_SECTIONS_TO_CROSSING = 13;

const int TIME_GATE_WARNING_BEFORE_TRAIN_MS = 7000;
const int TIME_GATE_DOWN_BEFORE_TRAIN_MS = 5000;
const int TIME_GATE_DOWN_AFTER_TRAIN_MS = 2000;
const int TIME_GATE_DOWN_BEFORE_TRAIN_CYCLES = TIME_GATE_DOWN_BEFORE_TRAIN_MS / CYCLE_PERIOD_MS;
const int TIME_GATE_DOWN_AFTER_TRAIN_CYCLES = TIME_GATE_DOWN_AFTER_TRAIN_MS / CYCLE_PERIOD_MS;

const int PIN_SENSOR = 0;
const int PIN_LEFT_LIGHT = 2;
const int PIN_RIGHT_LIGHT = 3;
const int PIN_STATUS_LIGHT_ARRIVAL = 4;
const int PIN_STATUS_LIGHT_DEPARTURE = 5;
const int PIN_BUZZER = 6;
const int PIN_SERVO = 7;

// Enums and globals
enum sensorState {
  out, entering, in, exiting
}
sensorState = out;

enum crossingState {
  up, warning, lowering, down, raising
}
crossingState = up;

Servo gateServo;
int sensorThreshold = 0;
long trainArrivalCountDownMS = 0;
long trainDepartureCountDownMS = 0;
int bellCycleCounter = 0;
int leftLightCycleCounter = 0;
int rightLightCycleCounter = LIGHT_BLINK_HALF_CYCLES;
float crossingPosition = CROSSING_POSITION_RAISED;


/*
One time initializations
*/
void setup()
{
  pinMode(PIN_LEFT_LIGHT, OUTPUT);
  pinMode(PIN_RIGHT_LIGHT, OUTPUT);
  pinMode(PIN_STATUS_LIGHT_ARRIVAL, OUTPUT);
  pinMode(PIN_STATUS_LIGHT_DEPARTURE, OUTPUT);
  pinMode(PIN_BUZZER, OUTPUT);
 
  // we assume that a train is not in the sensor at startup
  sensorThreshold = analogRead(PIN_SENSOR) + SENSOR_DELTA_THRESHOLD;

  gateServo.attach(PIN_SERVO);
  gateServo.write(CROSSING_POSITION_RAISED);

  Serial.begin(9600);
}

/*
Main control loop.
Check the sensor, update outputs, and then wait the cycle period.
*/
void loop()
{
  checkSensor();
  updateTimers();
  updateStatusLights();
  updateCrossingState();
  updateBells();
  updateLights();
  updateGatePosition();
  delay(CYCLE_PERIOD_MS);
}


/*
 Check sensor and update transitions or states
 */
void checkSensor()
{
  if (isTrainPresentAtSensor()) {
    switch (sensorState) {
      case in:
        // still in...
        break;
      case entering:
        Serial.println("\nsensor -> in");
        sensorState = in;
        break;
      case out:
      case exiting:
        Serial.println("\nsensor -> entering");
        sensorState = entering;
        break;
    }
  } else {
    switch (sensorState) {
      case in:
      case entering:
        Serial.println("\nsensor -> exiting");
        sensorState = exiting;
        break;
      case out:
        break;
      case exiting:
        Serial.println("\nsensor -> out");
        sensorState = out;
        break;
    }  
  }
}

/*
 Set the timers when a train arrives,
 increment the departure timer if a train is still in the sensor,
 decrement the timers if a train is on its way
 */
void updateTimers() {
  switch (sensorState) {
    case in:
      trainDepartureCountDownMS += CYCLE_PERIOD_MS;
      break;
    case entering:
      // is this a new train or an additional train?
      if (trainDepartureCountDownMS > 0) {
        // it is an additional train...
        // leave the arrival time as-is, add the time it takes for the new train to arrive on the departure timer
        Serial.println("\nAdditional train detected...");
        trainDepartureCountDownMS = calculateTrainArrivalTimeMS() + CYCLE_PERIOD_MS + TIME_GATE_DOWN_AFTER_TRAIN_MS;  
        // Serial.print("Arrival: ");
        // Serial.print(trainArrivalCountDownMS);
        // Serial.print("Departure: ");
        // Serial.println(trainDepartureCountDownMS);  
      } else {
        // it is a new train...
        Serial.println("\nNew train detected...");
        trainArrivalCountDownMS = calculateTrainArrivalTimeMS();
        trainDepartureCountDownMS = trainArrivalCountDownMS + CYCLE_PERIOD_MS + TIME_GATE_DOWN_AFTER_TRAIN_MS;
        // Serial.print("Arrival: ");
        // Serial.print(trainArrivalCountDownMS);
        // Serial.print("Departure: ");
        // Serial.println(trainDepartureCountDownMS);  
      }
      break;
    case out:    
    case exiting:
     // do nothing additional
     break;
  }
 
  if (trainArrivalCountDownMS > 0) {
    trainArrivalCountDownMS -= CYCLE_PERIOD_MS;
  }
 
  if (trainDepartureCountDownMS > 0) {
    trainDepartureCountDownMS -= CYCLE_PERIOD_MS;
  }
}
 

/*
 Manage crossing state transitions
 */
void updateCrossingState() {
  switch (crossingState) {
    case up:
      if ((trainDepartureCountDownMS > 0) && (trainArrivalCountDownMS < TIME_GATE_WARNING_BEFORE_TRAIN_MS)) {
        Serial.println("\ngate up -> warning");
        crossingState = warning;
      }
      break;
    case warning:
      if (trainArrivalCountDownMS < TIME_GATE_DOWN_BEFORE_TRAIN_MS) {
        Serial.println("\ngate warning -> lowering");
        crossingState = lowering;
      }
      break;
    case lowering:
      if (crossingPosition <= CROSSING_POSITION_LOWERED) {
        Serial.println("\ngate lowering -> down");
        crossingState = down;      
      } else {
        crossingPosition -= CROSSING_DEGREES_PER_CYCLE;
      }
      break;
    case down:
      if (trainDepartureCountDownMS <= 0) {
        Serial.println("\n(expected train departure from gate)");
        Serial.println("\ngate down -> raising");
        crossingState = raising;
      }
      break;
    case raising:
      if (crossingPosition >= CROSSING_POSITION_RAISED) {
        Serial.println("\ngate raising -> up");
        crossingState = up;      
      } else {
        crossingPosition += CROSSING_DEGREES_PER_CYCLE;
      }
      break;
  }
}



/*
We have one light to show the arrival countdown timer > 0 and
another light to show the departure countdown timer > 0
 */
void updateStatusLights() {
  if (trainArrivalCountDownMS > 0) {
    digitalWrite(PIN_STATUS_LIGHT_ARRIVAL, HIGH);
  } else {
    digitalWrite(PIN_STATUS_LIGHT_ARRIVAL, LOW);
  }
  
  if (trainDepartureCountDownMS > 0) {
    digitalWrite(PIN_STATUS_LIGHT_DEPARTURE, HIGH);
  } else {
    digitalWrite(PIN_STATUS_LIGHT_DEPARTURE, LOW);
  }
}


/*
Helper to determine if the train is in the sensor
*/
boolean isTrainPresentAtSensor() {
  int sensorValue = analogRead(PIN_SENSOR);
  // Serial.println(sensorValue);
  if (analogRead(PIN_SENSOR) > sensorThreshold) {
    Serial.print("S");
    return true;
  } else {
    return false;
  }
}

/*
We do a very simplistic calculation with the assumption that all
trains move at the same speed.  If we had a better sensor we could
figure out how fast an individual train was going
*/
int calculateTrainArrivalTimeMS() {
  return TRAIN_SPEED_MS_PER_SECTION * TRAIN_SECTIONS_TO_CROSSING;
}


/*
Bells only ring during the initial warning and
when the gate is lowering
*/
void updateBells()
{
  switch (crossingState) {
    case warning:
    case lowering:
      if (bellCycleCounter == 0) {
        Serial.print("(B!)");
        tone(PIN_BUZZER, BELL_TONE_FREQUENCY, BELL_DURATION);
        bellCycleCounter = BELL_RING_CYCLES;
      } else {
        bellCycleCounter--;
      }
      break;
  }
}


/*
Lights flash continuously when the gate is not up
*/
void updateLights()
{
  switch (crossingState) {
    case up:
      digitalWrite(PIN_LEFT_LIGHT, LOW);
      digitalWrite(PIN_RIGHT_LIGHT, LOW);
      break;
    case warning:
    case lowering:
    case down:
    case raising:
      if (leftLightCycleCounter == 0) {
        Serial.print("(LL)");
        digitalWrite(PIN_LEFT_LIGHT, HIGH);
        digitalWrite(PIN_RIGHT_LIGHT, LOW);
        leftLightCycleCounter = LIGHT_BLINK_CYCLES;
        rightLightCycleCounter--;
      } else if (rightLightCycleCounter == 0) {
        Serial.print("(RL)");
        digitalWrite(PIN_LEFT_LIGHT, LOW);
        digitalWrite(PIN_RIGHT_LIGHT, HIGH);
          rightLightCycleCounter = LIGHT_BLINK_CYCLES;
        leftLightCycleCounter--;
      } else {
        leftLightCycleCounter--;
        rightLightCycleCounter--;
      }
      break;
  }
}

/*
Manage incremental changes to the servo position
*/
void updateGatePosition()
{
  switch (crossingState) {
     case lowering:
       if (crossingPosition > CROSSING_POSITION_LOWERED) {
         crossingPosition -= CROSSING_DEGREES_PER_CYCLE;
         gateServo.write(crossingPosition);  // Move to next position
       }
       break;
     case raising:
       if (crossingPosition < CROSSING_POSITION_RAISED) {
         crossingPosition += CROSSING_DEGREES_PER_CYCLE;
         gateServo.write(crossingPosition);  // Move to next position
       }
       break;
  }
}
[/code]

this is the code i found that i would like to altar to my needs but unsure how to do it i have no coding experience I can tell you where i have things plugged but not sure how to altar to my needs

pin 2,3 are the leds pins 5.6 are servo pin 9 to act as switch to activate external sound card pins 4,7 will be the reed switches servos have external powersource

oh and the birthday is may second.Thats why im freaking out to get this finished i have been building the table for 3 months its down to the finishing touches, applying trees and detail and getting these crossing gates to work. I tried going through a few tutorials an how to code but i cant learn fast enough. Its tough to teach an old dog new tricks. LOL

Ok, I should finish something before then this evening I will try to put your code on Arduino and see what it does.

Enrico

Great! This helps me a lot

Enrico

I found a different set up real close to what i want. I dont know how to add the reed switches and eliminate the yellow light

[code]
//Level_crossing

#include <Servo.h>
 Servo myservo1; // create servo object to control a servo
 Servo myservo2;
 // a maximum of eight servo objects can be created
 int pos = 0; // variable to store the servo position
 int led1 = 11 ;// define RED2 LED Interface
 int led2 = 10 ;// define RED1 LED Interface
 int led3 = 9 ;// define Yellow LED Interface
 int buttonpin = 3; // define the obstacle avoidance sensor interface
 int val ;// define numeric variables val
 void setup ()
 {
 pinMode (led1, OUTPUT) ;// define LED as output interface
 pinMode (led2, OUTPUT) ;// define LED as output interface
 pinMode (led3, OUTPUT) ;// define LED as output interface
 pinMode (buttonpin, INPUT) ;// define the obstacle avoidance sensor output interface
 myservo1.attach(8); // attaches the servo on pin 9 to the servo object
 myservo2.attach(7); // attaches the servo on pin 8 to the servo object
 }
 void loop ()
 {
 val = digitalRead (buttonpin) ;// digital interface will be assigned a value of 3 to read val
 if (val == LOW) // When the obstacle avoidance sensor detects a signal, LED flashes
 {
 myservo1.write(90); // tell servo to go to position in variable 'pos'
 myservo2.write(90);
 flashLights();

 }
 else
   
 {
 myservo1.write(0); // tell servo to go to position in variable 'pos'
 myservo2.write(0);
 digitalWrite (led1, LOW);
 digitalWrite (led2, LOW);
 digitalWrite (led3, LOW);
 }
}
void flashLights() {
 digitalWrite(led3, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(2000); // wait for a second
 digitalWrite(led3, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led1, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led1, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led2, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led2, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led1, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led1, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led2, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led2, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led1, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led1, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led2, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led2, LOW); // turn the LED off by making the voltage LOW
  
  digitalWrite(led1, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led1, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led2, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led2, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led1, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led1, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led2, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(200); // wait for a second
 digitalWrite(led2, LOW); // turn the LED off by making the voltage LOW

 digitalWrite(led3, HIGH); // turn the LED on (HIGH is the voltage level)
 delay(1000); // wait for a second
 digitalWrite(led3, LOW); // turn the LED off by making the voltage LOW
}
[/code]

I appreciate you taking the time to help me with this your awesome!!

I appreciate you taking the time to help me with this your awesome!!