How to Control a DC Motor using Optocouplers with an H-Bridge -- DC to Daylight 18

Hello All,

It was brought to my attention in the YT comments that I professed about the need to avoid turning on same-side H/L transistors which would short the + and - rails, but didn't account for PQWM software timing which would cause an overlapping state.

The function in question:

void motion(int dir, int pwm)
{
    if(dir == FWD)
    {
        analogWrite(H1, pwm);
        analogWrite(H2, 0);
        analogWrite(L1, 0);
        analogWrite(L2, pwm);
    }
    if(dir == REV)
    {
        analogWrite(H1, 0);
        analogWrite(H2, pwm);
        analogWrite(L1, pwm);
        analogWrite(L2, 0);
    }
}

Now that my error has been revealed,... I have a simple solution in mind. How would you handle it? What would you change about this function?

-Derek

const byte FWD = 0;
const byte REV = 1;

const byte H1 = 3; // PWM pin 3
const byte H2 = 5; // PWM pin 5
const byte L1 = 6; // PWM pin 6
const byte L2 = 9; // PWM pin 9

const unsigned long DWELLTIME = 2000; // time mS to hold at max speed
const unsigned long PWMSTPTIME = 10; // mS delay between PWM changes
const unsigned long STOPTIME = 25; // mS delay between direction changes
const byte PWMMAXVAL = 255; // 8-bit PWM so 0 - 255


byte direction = FWD;


void stop() {
  analogWrite(H1, 0);
  analogWrite(H2, 0);
  analogWrite(L1, 0);
  analogWrite(L2, 0);
  delay(STOPTIME);
}

void motion(const byte dir, const byte duty) {
  static byte current_dir = 2; // keep track of current h-bridge direction, initialized to invalid state

  // Check for direction change (or first execution)
  if(dir != current_dir){
    stop();
    current_dir = dir;
  }
  
  switch(dir){
    case FWD:
      analogWrite(H1, duty);
      analogWrite(L2, duty);
     break;
    case REV:
      analogWrite(H2, duty);
      analogWrite(L1, duty);
      break;
  }
}

void ramp_pwm(const byte start, const byte end){
  if(start == end) return;
  const short step = end > start ? 1 : -1;
  
  // ramp profile
  for(short pwmvalue=start; pwmvalue != end; pwmvalue += step){
    motion(direction, pwmvalue);
    delay(PWMSTPTIME);
  }
}

void setup() {
  Serial.begin(9600);
}

void loop() {

  // ramp up profile
  ramp_pwm(0, PWMMAXVAL);

  // dwell in plateau
  delay(DWELLTIME);

  // ramp down profile
  ramp_pwm(PWMMAXVAL, 0);

  // swap direction
  direction ^= 1;
}

Something like this, maybe.
I tried to keep it relatively simple, but my sensibilities scream about using int when it's not necessary (or non-stdint types for that matter, but I compromised).

Ha. I cringed a little when I used int's as well, but it's a fine line - keeping a simple presentation vs. the most efficient way to write code.

Anyway, I like your solution!

Ha. I cringed a little when I used int's as well, but it's a fine line - keeping a simple presentation vs. the most efficient way to write code.

Anyway, I like your solution!