Help. I need the reverse of zero crossing

Question

Ok, I need some hunk of code to detect the peek not the zero crossing. ( this is the solution).

Problem: Toroid based power supply have inrush current problems. As when you turn on the power switch,

it is a random chance where on the sine wave it will be.

You can not start this a zero crossing as that is the I_max and will blow your fuse.

This solution must be only a primary side problem. I was thinking of a relay but a small triac is much faster.

Thanks

Cris

abrain · Accepted Answer

Yes, sorry Cris, I don’t think I explained it very well.

If you’re measuring the voltage (which I think you must be to find the zero crossing) then work out how much that voltage changed from the last sample you took, that change is smallest when you’re at the peak of the voltage.

You’ll need to take the absolute value of the difference between the two readings, to account for negative and positive going peaks, but it will let you fire the relay at exactly the right time,

I’ll see if I can sketch something out tomorrow to explain it better.

A

michaelkellett · Answer

Why do you need code - the simplest trick is to use an NTC current limiter. These people have a lovely web site: https://www.ametherm.com/ If you have to do it in code it might be easier to detect zero crossings and then add a suitable time (phase) delay to locate the next peak. MK

phoenixcomm · Answer

I have seen current limiters like Ametherms before. But the problem is that I have three toroidal power transformers, and for the first 20ms or so they draw I max so the idea is to turn them on one at a time about one second apart. I like your idea about using a delay from zero crossing. Since we know that (T=1/60) 1/60Hz = 0.0166666667 then by using T/2 = 0.00833333335 now I will have to check this on my scope and most likely fudge the result as I really want this to fire just at the start of the bottom of the peak curve ie just before the top. and on the way down. thanks for the help Great answer! Cris H.

abrain · Answer

Hi Cris, if you’re sampling fast enough, and measuring the input voltage rather than doing some simple thresholding, then why not actually base it on what you’re interested in? Measure the voltage, quickly work out the change from last time you sampled, and as that rate of change comes down to a nice low value, switch on?

That way you avoid dodgy time delays being affected by changes in frequency, etc, but you may have the issue of a working out the change on a noisy signal, depending on how you’re sampling circuit is filtered.

A

abrain · Answer

Hi Cris, don't these things always turn out more interesting than you expect when you have a look at them?! Here's what I've come up with.... My idea was basically to sample the voltage quite quickly (I think you're looking at 60Hz mains), so we get a good number of readings, and work out the difference between the latest reading and the previous one, effectively differentiating the signal. For a sine wave inout, that would give us something like the samples in the graph below (assuming you've got your input scaled nicely in the middle of the Arduino's 5V range). From the orange dots showing the delta, you can then see that you're effectively after the zero crossing of the delta signal to get at the peak. When I came to try it, I got quite a lot of noisy triggering when there was no signal there, so I've added an extra check to make sure the ADC reading is above 800 before triggering, which is about a 3.9V input signal. The (moderately) interesting bit is that to get some good sampling, I set up an interrupt routine using Timer1, so we've got 2kHz sampling out of an Arduino! It's based on some other code I found on a forum some time ago, hopefully it'll be of use! // Interrupt-driven ADC sampling from Jack Christensen 13 Jun 2013
// http://forum.arduino.cc/index.php?topic=171226.msg1276869#msg1276869

#define BAUD_RATE 9600
#define ADC_THRESHOLD 800 // if the actual voltage isn't above this, don't trigger

int timerCount = 0; // use to flash the LED at a sensible 2Hz rate
volatile int oldAdcVal; // keep the last reading so we can calculate a delta
volatile int lastDelta; // keep the old delta, so we can look for a zero crossing in that
boolean justPeaked = false; // flag to our main loop when we've just reached a peak

void setup(void)
{
 delay(1000);
 Serial.begin(BAUD_RATE);
 Serial.println("Setup...");

//set up the timer
 TCCR1B = 0; //stop the timer
 TCCR1A = 0;
 TIFR1 = 0xFF; //ensure all interrupt flags are cleared
 OCR1A = 999; //timer runs at 16MHz / 1000 / 8 (prescaler) = 2000Hz (500us between samples)
 OCR1B = 999;
 cli();
 TCNT1 = 0; //clear the timer
 TIMSK1 = _BV(OCIE1B); //enable timer interrupts
 sei();
 TCCR1B = _BV(WGM12) | _BV(CS11); //start the timer, ctc mode, prescaler 8

//set up the adc
 ADMUX = _BV(REFS0); //use AVcc as reference
 ADCSRA = _BV(ADEN) | _BV(ADATE) | _BV(ADIE); //enable ADC, auto trigger, interrupt when conversion complete
 ADCSRA |= _BV(ADPS2) | _BV(ADPS1) | _BV(ADPS0); //ADC prescaler: divide by 128
 ADCSRB = _BV(ADTS2) | _BV(ADTS0); //trigger ADC on Timer/Counter1 Compare Match B

pinMode(LED_BUILTIN, OUTPUT);
 Serial.println("Ready to go...");
}

void loop(void)
{
 if ( justPeaked ) {
 Serial.println(micros());
 Serial.flush();
 justPeaked = false;
 }
}

ISR(ADC_vect)
{
 int newAdcVal = ADC;
 int newDelta = newAdcVal - oldAdcVal;
 oldAdcVal = newAdcVal; // save the new reading to use in the next delta sum

// we make sure our actual reading is above a threshold to prevent
 // a lot of triggering from small signal noise
 if ( newAdcVal > ADC_THRESHOLD ) {
 // if we've had a zero crossing in our delta value,
 // we've just reached the peak of the waveform
 if ( ( lastDelta > 0 ) && ( newDelta < 0 ) ) {
 justPeaked = true;
 }
 }
 
 lastDelta = newDelta; // save the new delta value for next time
}

ISR(TIMER1_COMPB_vect)
{
 // this is simply to toggle the LED, the triggering of the
 // ADC happens automatically
 timerCount++;
 if ( timerCount == 500 ) {
 digitalWrite(LED_BUILTIN, HIGH);
 }
 if ( timerCount == 1000 ) {
 digitalWrite(LED_BUILTIN, LOW);
 timerCount = 0;
 }
} I hooked this up to my Arduino Micro, with the signal generator connected between pins GND and A5, with a 3Vpk-pk sine wave signal and 2.5Vdc offset, at 60Hz. So there you go - hopefully you can replace that serial output part in the loop() function with what you need to drive your relays, and you're done! A

Help. I need the reverse of zero crossing

Top Replies